plugins {
    alias(libs.plugins.kotlin.jvm)
    alias(libs.plugins.ktlint)
    `maven-publish`
}

repositories {
    mavenCentral()
    maven {
        url = uri("https://gitea.davygora.duckdns.org/api/packages/yura/maven")
    }
}

group = "org.duckdns.davygora"
version = "0.1"

dependencies {
    // Main

    implementation(libs.kotlin.reflect)

    implementation(libs.memoize)

    // Test

    testImplementation(libs.bundles.test)
    testRuntimeOnly(libs.bundles.junit.platform)
}

kotlin {
    compilerOptions {
        freeCompilerArgs.addAll("-Xjsr305=strict")
    }
}

kotlin {
    jvmToolchain {
        languageVersion = JavaLanguageVersion.of(21)
        vendor = JvmVendorSpec.ADOPTIUM
    }
}

tasks.named<Test>("test") {
    useJUnitPlatform()
}

ktlint {
    version =
        libs.versions.ktlint.library
            .get()
}

publishing {
    publications {
        create<MavenPublication>("maven") {
            from(components["java"])
        }
    }

    repositories {
        maven {
            name = "gitea"
            url =
                uri(
                    "https://gitea.davygora.duckdns.org/api/packages/yura/maven",
                )
            credentials {
                username = System.getenv("MAVEN_USERNAME")
                password = System.getenv("MAVEN_PASSWORD")
            }
        }
    }
}

tasks.wrapper {
    gradleVersion = libs.versions.gradle.get()
    distributionType = Wrapper.DistributionType.BIN
}